- Added windows llama proxy

- Added terraform-mcp
- Added S3 storage to gitea
- Changed context size for windows LLMs
- Changed number of cores for VMs, added P2000 support

terraform/modules/apps/terraform-mcp/config.tf

@@ -0,0 +1,4 @@
+locals {
+  app_version = var.tag
+  app_fqdn    = var.fqdn
+}

terraform/modules/apps/terraform-mcp/ingress.tf

@@ -0,0 +1,24 @@
+resource "kubernetes_ingress_v1" "terraform_mcp" {
+  metadata {
+    name      = "ingress"
+    namespace = kubernetes_namespace.terraform_mcp.metadata[0].name
+  }
+
+  spec {
+    rule {
+      host = var.fqdn
+      http {
+        path {
+          backend {
+            service {
+              name = kubernetes_service.terraform_mcp.metadata[0].name
+              port {
+                number = 80
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+}

terraform/modules/apps/terraform-mcp/main.tf

@@ -0,0 +1,131 @@
+resource "kubernetes_namespace" "terraform_mcp" {
+  metadata {
+    name = "terraform-mcp"
+  }
+}
+
+resource "kubernetes_service_account" "terraform_mcp" {
+  metadata {
+    name      = "terraform-mcp-sa"
+    namespace = kubernetes_namespace.terraform_mcp.metadata[0].name
+  }
+
+  automount_service_account_token = false
+}
+
+resource "kubernetes_deployment" "terraform_mcp" {
+  metadata {
+    name      = "terraform-mcp"
+    namespace = kubernetes_namespace.terraform_mcp.metadata[0].name
+    labels = {
+      app = "terraform-mcp"
+    }
+  }
+
+  spec {
+    replicas = 1
+
+    selector {
+      match_labels = {
+        app = "terraform-mcp"
+      }
+    }
+
+    strategy {
+      type = "Recreate"
+    }
+
+    template {
+      metadata {
+        labels = {
+          app = "terraform-mcp"
+        }
+      }
+
+      spec {
+        service_account_name            = kubernetes_service_account.terraform_mcp.metadata[0].name
+        automount_service_account_token = false
+
+        container {
+          name  = "terraform-mcp"
+          image = "hashicorp/terraform-mcp-server:${local.app_version}"
+
+          env {
+            name  = "TRANSPORT_MODE"
+            value = "streamable-http"
+          }
+
+          env {
+            name  = "TRANSPORT_PORT"
+            value = "8084"
+          }
+
+          env {
+            name  = "TRANSPORT_HOST"
+            value = "0.0.0.0"
+          }
+
+          security_context {
+            allow_privilege_escalation = false
+            privileged                 = false
+
+            capabilities {
+              drop = ["ALL"]
+            }
+          }
+
+          port {
+            name           = "http"
+            container_port = 8084
+            protocol       = "TCP"
+          }
+
+          liveness_probe {
+            http_get {
+              path = "/health"
+              port = "http"
+            }
+            initial_delay_seconds = 10
+            period_seconds        = 15
+          }
+
+          readiness_probe {
+            http_get {
+              path = "/health"
+              port = "http"
+            }
+            initial_delay_seconds = 5
+            period_seconds        = 10
+          }
+        }
+      }
+    }
+  }
+}
+
+resource "kubernetes_service" "terraform_mcp" {
+  metadata {
+    name      = "terraform-mcp-service"
+    namespace = kubernetes_namespace.terraform_mcp.metadata[0].name
+  }
+
+  spec {
+    selector = {
+      app = "terraform-mcp"
+    }
+
+    port {
+      name        = "http"
+      port        = 80
+      target_port = 8084
+    }
+
+    type = "ClusterIP"
+  }
+
+  lifecycle {
+    ignore_changes = [
+      metadata[0].annotations
+    ]
+  }
+}

terraform/modules/apps/terraform-mcp/provider.tf

@@ -0,0 +1,9 @@
+terraform {
+  required_version = "~>1.8"
+  required_providers {
+    kubernetes = {
+      source  = "hashicorp/kubernetes"
+      version = "2.36.0"
+    }
+  }
+}

terraform/modules/apps/terraform-mcp/variables.tf

@@ -0,0 +1,15 @@
+variable "fqdn" {
+  description = "FQDN for the service"
+  type        = string
+}
+
+variable "tag" {
+  description = "Image tag to deploy"
+  type        = string
+  default     = "1.0.0"
+}
+
+variable "persistent_folder" {
+  description = "Path for persistent data on the host"
+  type        = string
+}