Add Nextcloud deployment and configuration

- Introduced Nextcloud module with Kubernetes resources including deployment, service, ingress, and cron job.
- Configured Apache settings for Nextcloud with SSL support and compression.
- Created secrets for mail and admin credentials.
- Added necessary environment variables for Nextcloud configuration.
- Removed unused Scaleway access and secret keys from secrets and variables.
- Updated CoreDNS module to support custom host overrides.
- Implemented backup bucket policies and lifecycle rules for Scaleway object storage.
- Enhanced IAM policies and applications for backup and email services.
- Added outputs for backup bucket and API keys.

terraform/modules/apps/nextcloud/ingress.tf

@@ -0,0 +1,67 @@
+resource "kubernetes_service" "nextcloud_apache" {
+  metadata {
+    name      = "http"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+  }
+  spec {
+    port {
+      port        = var.tls_enabled ? 443 : 80
+      target_port = var.tls_enabled ? 443 : 80
+    }
+    selector = {
+      app = "nextcloud"
+    }
+    cluster_ip = "None"
+  }
+}
+
+resource "kubernetes_ingress_v1" "nextcloud_ingress" {
+  depends_on = [
+    kubernetes_deployment.nextcloud_apache
+  ]
+  metadata {
+    name      = "ingress"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+
+    annotations = merge({
+      "kubernetes.io/ingress.class"                         = "public"
+      "cert-manager.io/cluster-issuer"                      = "letsencrypt-prod"
+      "kubernetes.io/tls-acme"                              = "true"
+      "nginx.ingress.kubernetes.io/ssl-redirect"            = "true"
+      "nginx.ingress.kubernetes.io/proxy-body-size"         = "4G"
+      "nginx.ingress.kubernetes.io/proxy-request-buffering" = "on"
+      "nginx.ingress.kubernetes.io/proxy-buffer-size"       = "32k"
+      "nginx.ingress.kubernetes.io/proxy-buffers-number"    = "16"
+      "nginx.ingress.kubernetes.io/server-snippet"          = file("${path.module}/resources/nextcloud-server-snippet.conf")
+      },
+      var.tls_enabled ? {
+        "nginx.org/ssl-services"                       = "http"
+        "nginx.org/ssl-redirect"                       = "true"
+        "nginx.org/redirect-to-https"                  = "true"
+        "nginx.ingress.kubernetes.io/backend-protocol" = "HTTPS"
+      } : {}
+    )
+  }
+  spec {
+    tls {
+      hosts       = [var.fqdn]
+      secret_name = "nextcloud-tls"
+    }
+    rule {
+      host = var.fqdn
+      http {
+        path {
+          backend {
+            service {
+              name = "http"
+              port {
+                number = var.tls_enabled ? 443 : 80
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+}
+